Can't stomp enemies when flashing (after taking damage)

omniretro

New member
I'm using Dale Coop's 2-Player Platform module, and the only maybe-relevant changes I've made have been to lengthen the invincibility time after taking damage in Constants.asm (though this was happening before I made that change, it's just more noticeable now). Whenever either of my players take damage, they flash and are invincible like they're supposed to be, but they're also unable to stomp enemies and kill them (as they are able to when they aren't invincible). Is there an easy way of fixing that? So far I've tried adjusting settings for the players and for enemies but I can't seem to find anything that would change this, so I'm assuming there's an ASM change that needs to be made, I just don't now where.

Any help is appreciated!
 

dale_coop

Moderator
Staff member
Hmm... could be a bug in my module.... or have you made any modification in the Handle Object Collision script or the Handle Monster Hurt script?

Couldn't reproduce the issue... is it when your player 1 is taking damage?
Platformer or Adventure module?
 

omniretro

New member
dale_coop said:
Hmm... could be a bug in my module.... or have you made any modification in the Handle Object Collision script or the Handle Monster Hurt script?

Couldn't reproduce the issue... is it when your player 1 is taking damage?
Platformer or Adventure module?

I looked, and it doesn't appear I've made any changes to HandleObjectCollision_DC.asm or HandleMonsterHurt.asm.

This happens when either player 1 or player 2 take damage in the Platformer module (haven't tried in the Adventure module because I've not really cracked that one open yet).
 

dale_coop

Moderator
Staff member
Can't reproduce the issue with the platfomer module.
So I guess you have something incorrect in your project.
Could you share your HandleObjectCollision_DC.asm, your HandleMonsterHurt.asm and your HandlePlayerHurt.asm scripts?

I will check with your scripts on my projects.
 

omniretro

New member
dale_coop said:
Can't reproduce the issue with the platfomer module.
So I guess you have something incorrect in your project.
Could you share your HandleObjectCollision_DC.asm, your HandleMonsterHurt.asm and your HandlePlayerHurt.asm scripts?

I will check with your scripts on my projects.

Sure!

HandleObjectCollisions.asm (I don't seem to have a "_DC" version of this one in /Basic_NoScroll_TwoPlayers/System):

Code:
;; LOAD OBJECT 00
;; OUTER LOOP
;; CHECK IF ACTIVE, IF NOT, SKIP OBJECT
;; LOAD self-collision-box
;; START OBJECT COLLISION LOOP
	;; LDA ONE MORE THAN CURRENT OBJECT
	;; CHECK IF ACTIVE.  IF NOT, SKIP THIS other
	;; IF IT IS ACTIVE, then we have to play them against each other.
		;; IS self object hurt by monsters?  If so, and other object is a monster, respond.
		;; IS self object hurt by weapons?  If so, and other object is a weapon, respond.
		;; at this point, we can still gauge whether or not it's affected by player, like with powerups.
		;; ADD one to the object being checked, loop through other objects.
;; increase object, return to outer loop.  Repeat thorugh all self objects.

;; ObjectFlags:
;; 7 - 6 - 5 - 4 - 3 - 2 - 1 - 0
;  |   |   |   |   |   |   |   + -- PERSISTENT (especially good for player!)
;  |   |   |   |   |   |   +------- player type
;  |   |   |   |   |   + ---------- player weapon/projectile type
;  |   |   |   |   +--------------- monster type
;  |   |   |   +------------------- monster weapon/projectile type
;  |   |   +----------------------- pickup / power up
;  |   + -------------------------- target type 
;  +------------------------------- NPC type

;; player type checks monster, mosnter weapon, and pickup.
;; player weapon checks monster and target.
;; nothing else needs checking, as it would all be handled by those two steps.
;; so if it's a monster, do nothing.  if it's a monster projectile, do nothing. 
;; if it's a pickup, or a target, or it ignores all collisions, do nothing.
;; only if it's #%00000110, do something.



HandleObjectCollisions:

	LDA update_screen
	BEQ notChangingScreens
	rts
notChangingScreens:
	
	LDA npc_collision
	AND #%11111110
	STA npc_collision

	;LDA currentBank
	;STA prevBank
	;LDY #BANK_ANIMS
	;JSR bankswitchY
	
	LDX #$00
CollisionOuterLoop:
	TXA
	STA tempx
	LDA Object_status,x
	AND #%10000000
	BNE continueObjectCollisions_objectIsActive
	JMP doneWithThisObjectCollision
continueObjectCollisions_objectIsActive:
	LDA Object_status,x
	AND #%00000100 ;; is ot off screen
	BEQ continueObjectCollisions_objectIsOnScreen
	JMP doneWithThisObjectCollision
continueObjectCollisions_objectIsOnScreen
	LDA Object_status,x
	AND #%00000011
	BEQ continueObjectCollisions_objectIsNotHurtOrInvincible
	JMP doneWithThisObjectCollision
continueObjectCollisions_objectIsNotHurtOrInvincible
	;LDY Object_type,x
	;LDA ObjectFlags,y
	LDA Object_flags,x
	AND #%00000110
	BNE continueObjectCollisions_onlyPlayerTypesCheck
	JMP doneWithThisObjectCollision
continueObjectCollisions_onlyPlayerTypesCheck:
	;; this is either a player or player projectile type of object.
	;; all other types will be taken care of by iterating through these two types.
	;; first, check if it's player type.
	;LdA ObjectFlags,y
	LDA Object_flags,x
	AND #%00000010
	BNE isPlayerTypeForCollision
	JMP notPlayerType_forObjectCollision
isPlayerTypeForCollision:
	LDA player1_object
	STA colX
	;; is player type for object collision
	;; player's index is loaded into tempx
	JSR GetSelfCollisionBox
	;; now we have the collision box for self object
	;; next we loop through objects.
	
	LDX #$00
LoopThroughOtherObjects_player:
	CPX tempx
	BNE dontSkipThisOtherObject
	JMP skipThisOtherObject ;; other object IS the player, the one doing the counting..
dontSkipThisOtherObject:
	LDA Object_status,x
	AND #%00000100
	BEQ dontSkipThisOtherObject_becauseOnScreen
	JMP skipThisOtherObject ;; because it was off screen.
dontSkipThisOtherObject_becauseOnScreen:

	JSR GetOtherCollisionBox
	

	;; now we can do all the compares
	LDA selfNT_R
	CMP otherNT_L
	BCC + ;; no player object collision
	BNE ++ ;; is still possible to see collision.
	LDA selfRight
	CMP otherLeft
	BCC + ;; no player object collision
++ ;; it is still possible there is a collision here.
	LDA otherNT_R
	CMP selfNT_L
	BCC +
	BNE +++
	LDA otherRight
	CMP selfLeft
	BCC +
	
+++ ;; there was a collision here
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	LDA otherBottom
	CMP selfTop
	BCC +
	LDA selfBottom
	CMP otherTop
	BCC +

	JMP DoPlayerObjectCollision

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	
+ ;; there is no collision here horizontally.
	JMP noPlayerObjectCollision

DoPlayerObjectCollision:
	LDA Object_flags,x
	AND #%10000000 ;; is it an NPC
	BNE isAnNPC
	;; is not an NPC
	JMP isNotAnNPCcollision
isAnNPC:
	;;;; do npc stuff.
	LDA npc_collision
	ORA #%00000001
	STA npc_collision
	;;;; enables a button to be used to activate a textbox.
	LDA Object_ID,x
	STA textVar
	;LDA gameHandler
	;ORA #%00100000
	;STA gameHandler

	JMP skipThisOtherObject
	
isNotAnNPCcollision:	
	LDA Object_flags,x
	;LDA ObjectFlags,y
	AND #%00011000 ;; is it a monster type?
	BNE otherIsAMonsterTypeCollision
	JMP otherIsNotAMonsterTypeCollision
otherIsAMonsterTypeCollision:
	LDA Object_status,x
	AND #HURT_STATUS_MASK ;; if the monster is hurt, it can't hurt us
	BEQ yesPlayerObjectCollision
	JMP noPlayerObjectCollision
yesPlayerObjectCollision:
	
	LDA Object_vulnerability,x
	AND #%00000010 ;; in this module, this is ignore player collision
	BEQ doPlayerHurt
	JMP	noPlayerObjectCollision
doPlayerHurt:
	;;;observe health
	TXA
	STA tempx ;; object is in tempx.
	LDX player1_object
	LDA Object_status,x
	AND #HURT_STATUS_MASK
	BEQ playerWasNotHurtDuringCollision
	JMP playerWasHurtDuringCollision
playerWasNotHurtDuringCollision:
	
	LDA Object_vulnerability,x
	AND #%01000000 ;; is he lethal invincible?
	BNE isLethalInvincible
	JMP notLethalInvincible
isLethalInvincible:
	LDX tempx
	LDA Object_x_hi,x
	STA temp
	LDA Object_y_hi,x
	STA temp1
	CreateObject temp, temp1, #OBJ_MONSTER_DEATH, #$00, currentNametable ;; create "splat"
	LDX tempx
	
	;;; ordinarily we'll want to destroy the instance.
	 DeactivateCurrentObject
	;; incrase score, you killed a monster
	PlaySound #SND_SPLAT
	TXA
	STA tempx
	AddValue #$08, myScore, #$01, #$00

	;;; we also need to set up the routine to update the HUD
	;; for this to work right, health must be a "blank-then-draw" type element.
	;STA hudElementTilesToLoad
	;	LDA #$00
	;	STA hudElementTilesMax
		; LDA DrawHudBytes
		; ora #HUD_myScore
		; STA DrawHudBytes
	UpdateHud HUD_myScore
	LDX tempx
	;;
	
	JMP skipThisOtherObject
	
notLethalInvincible:
	
	;;;;;;;;;;;;;;;;;
	;;;;;;;;; WHAT HAPPENS WHEN PLAYER IS HURT
	.include SCR_PLAYER_HURT_SCRIPT
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	
	
playerWasHurtDuringCollision:	
	LDX tempx
	JMP skipThisOtherObject
otherIsNotAMonsterTypeCollision:
	;LDA ObjectFlags,y
	LDA Object_flags,x
	AND #%00100000 ;; is it a 'collectable'?
	BEQ otherIsNotAcollectable
	;;;; IS A pickup / power up
	DeactivateCurrentObject ;; makes the other object go away
							;; since other object is loaded in X
							
;;=========== WHAT DO YOU WANT TO HAVE HAPPEN WHEN YOU COLLECT THIS ITEM?

	JSR HandlePickupPowerup

	
otherIsNotAcollectable:
noPlayerObjectCollision:	
skipThisOtherObject:
	INX
	CPX #TOTAL_MAX_OBJECTS
	BEQ doneLoopThroughOtherObjects_player
	JMP LoopThroughOtherObjects_player
doneLoopThroughOtherObjects_player:
	;; end of player collision
	LDX tempx ;; restore x
	JMP doneWithThisObjectCollision
	
	
	
notPlayerType_forObjectCollision:
	;; is of player weapon type.
	JSR GetSelfCollisionBox
	;; now we have the collision box for self object
	;; next we loop through objects.
	LDX #$00
LoopThroughOtherObjects_weapon:

	CPX tempx
	BNE dontskipThisOtherObject_weapon
	JMP skipThisOtherObject_weapon
dontskipThisOtherObject_weapon
	JSR GetOtherCollisionBox
	;; now we can do all the compares
	LDA selfNT_R
	CMP otherNT_L
	BCC + ;; no player object collision
	BNE ++ ;; is still possible to see collision.
	LDA selfRight
	CMP otherLeft
	BCC + ;; no player object collision
++ ;; it is still possible there is a collision here.
	LDA otherNT_R
	CMP selfNT_L
	BCC +
	BNE +++
	LDA otherRight
	CMP selfLeft
	BCC +
	
+++ ;; there was a collision here
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	LDA otherBottom
	CMP selfTop
	BCC +
	LDA selfBottom
	CMP otherTop
	BCC +

	JMP doWeaponObjectCollision

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	
+ ;; there is no collision here horizontally.
	JMP noWeaponObjectCollision
doWeaponObjectCollision:
	;; go through the different types of collision possible.
	;; first, check monster OR monser projectile, as that should lead to hurt/death
	;LDY Object_type,x
	;LDA ObjectFlags,y
	LDA Object_flags,x
	AND #%00001000 ;; is it a monster type?
	;;; if you'd like the player weapon to ALSO destroy projectiles
	;;; use #%00011000 here
	BNE otherIsMonsterTypeCollision_weapon
	JMP otherIsNotAMonsterTypeCollision_weapon
otherIsMonsterTypeCollision_weapon:
;;;;;;;;;;;;;;;;;;;;;;;;
	TXA
	PHA
	.include SCR_HANDLE_HURT_MONSTER
	PLA
	TAX
	;;; if monster dies, count monsters
	;; right now, he always dies, so count the monsters.
	JSR countAllMonsters	
	

	
otherIsNotAMonsterTypeCollision_weapon:
	
noWeaponObjectCollision:	
skipThisOtherObject_weapon:
	INX
	CPX #TOTAL_MAX_OBJECTS
	BEQ doneWithLoopingThroughWeaponObjects
	JMP LoopThroughOtherObjects_weapon
doneWithLoopingThroughWeaponObjects:
	
	
	
	;; end of player collision
	LDX tempx ;; restore x
	JMP doneWithThisObjectCollision
	
	
	
	
doneWithThisObjectCollision:
	LDX tempx
	INX
	CPX #TOTAL_MAX_OBJECTS
	BEQ doneWithAllObjects
	JMP CollisionOuterLoop
doneWithAllObjects:
	
	
	;LDY prevBank
	;JSR bankswitchY
	RTS
	
	
	
	
	
	
GetSelfCollisionBox:	
	LDA Object_x_hi,x
	CLC
	ADC Object_left,x
	STA selfLeft

	LDA Object_x_hi,x
	CLC
	ADC Object_right,x
	STA selfRight

	LDA Object_y_hi,x
	CLC
	ADC Object_top,x
	STA selfTop
	
	LDA Object_y_hi,x
	CLC
	ADC Object_bottom,x
	STA selfBottom
	LDA Object_x_hi,x
	CLC
	ADC Object_origin_x,x
	STA selfCenterX
	LDA Object_y_hi,x
	CLC
	ADC Object_origin_y,x
	STA selfCenterY
	

	RTS
	
GetOtherCollisionBox:
	LDA Object_x_hi,x
	CLC
	ADC Object_left,x
	STA otherLeft

	LDA Object_x_hi,x
	CLC
	ADC Object_right,x
	STA otherRight


	LDA Object_y_hi,x
	CLC
	ADC Object_top,x

	STA otherTop
	LDA Object_y_hi,x
	CLC
	ADC Object_bottom,x
	STA otherBottom
	LDA Object_x_hi,x
	CLC
	ADC Object_origin_x,x
	STA otherCenterX
	LDA Object_y_hi,x
	CLC
	ADC Object_origin_y,x
	STA otherCenterY
	

	RTS
	
	
	
	
	
	
	
DetermineRecoilDirection:

	;;;RECOIL
	;;First check for the abs x value
	LDA recoil_selfX
	SEC
	SBC recoil_otherX
	BCS absCheckDone
	EOR #$FF
	CLC
	ADC #$01
absCheckDone:
	STA temp
	LDA recoil_selfY
	SEC
	SBC recoil_otherY
	BCS absCheckDone2
	EOR #$FF
	CLC
	ADC #$01
absCheckDone2:
	CMP temp
	BCS vCol
	LDA recoil_selfX
	CMP recoil_otherX
	BCS recoilRight
	;; recoil left
	;LDX #$01
	LDA #RECOIL_SPEED_LO
	STA Object_h_speed_lo,x
	LDA #$00
	SEC
	SBC	#RECOIL_SPEED_HI
	STA Object_h_speed_hi,x
	LDA #$00
	STA Object_v_speed_hi,x
	STA Object_v_speed_lo,x
	LDA #%10000000
	STA temp1
	LDA Object_movement,x
	AND #%00000111
	ORA temp1
	STA Object_movement,x

	RTS
	
recoilRight:
	;LDX #$01
	LDA #RECOIL_SPEED_LO
	STA Object_h_speed_lo,x
	LDA	#RECOIL_SPEED_HI
	STA Object_h_speed_hi,x
	LDA #$00
	STA Object_v_speed_hi,x
	STA Object_v_speed_lo,x
	LDA #%11000000
	STA temp1
	LDA Object_movement,x
	AND #%00000111
	ORA temp1
	STA Object_movement,x

	RTS
	
vCol:
	LDA recoil_selfY
	CMP recoil_otherY
	BCS recoilDown
	;LDX #$01
	LDA #RECOIL_SPEED_LO
	STA Object_v_speed_lo,x
	LDA #$00
	SEC
	SBC	#RECOIL_SPEED_HI
	STA Object_v_speed_hi,x
	LDA #%00100000
	STA temp1
	LDA #$00
	STA Object_h_speed_hi,x
	STA Object_h_speed_lo,x
	LDA Object_movement,x
	AND #%00000111
	ORA temp1
	STA Object_movement,x

	RTS
	
recoilDown:
	;LDX #$01
	LDA #RECOIL_SPEED_LO
	STA Object_v_speed_lo,x
	LDA #RECOIL_SPEED_HI
	STA Object_v_speed_hi,x
	LDA #%00110000
	STA temp1
	LDA #$00
	STA Object_h_speed_hi,x
	STA Object_h_speed_lo,x
	LDA Object_movement,x
	AND #%00000111
	ORA temp1
	STA Object_movement,x
	
	RTS


HandleHurtMonster_DC.asm:

Code:
;;; what should we do with the monster?
        ;;; monster is loaded in x
        LDA Object_vulnerability,x
        AND #%00000100 ;; is it weapon immune?
        BEQ notWeaponImmune
        ;PlaySound #SFX_MISS
        JMP skipHurtingMonsterAndSound
    notWeaponImmune:
        
        LDA Object_status,x
        AND #HURT_STATUS_MASK
        BEQ dontskipHurtingMonster
        JMP skipHurtingMonster
    dontskipHurtingMonster:
        LDA Object_status,x
        ORA #%00000001
        STA Object_status,x
        LDA #HURT_TIMER
        STA Object_timer_0,x
        ;;; assume idle is in step 0
        ChangeObjectState #$00,#$02
        ;;;; unfortunately this recoil is backwards
        LDA Object_status,x
        AND #%00000100
        BNE skipRecoilBecauseOnEdge
        LDA Object_vulnerability,x
        AND #%00001000 
        BNE skipRecoilBecauseOnEdge ;; skip recoil because bit is flipped to ignore recoil
        
        LDA selfCenterX
        STA recoil_otherX
        LDA selfCenterY
        STA recoil_otherY
        LDA otherCenterX
        STA recoil_selfX
        LDA otherCenterY
        STA recoil_selfY
        JSR DetermineRecoilDirection
    skipRecoilBecauseOnEdge:
        LDA Object_health,x
        SEC
        SBC #$01
        CMP #$01
        BCC +
		JMP notMonsterDeath
	+

		LDA Object_x_hi,x
		STA temp
		LDA Object_y_hi,x
		STA temp1

		DeactivateCurrentObject
        PlaySound #SND_MONSTER_DEATH
        ;;;;;;;;;;;;;;;;;; ok, so now we also add points to score
        ;LDY Object_type,x
        ;LDA ObjectWorth,y
        ;STA temp
;       AddValue #$03, GLOBAL_Player1_Score, temp
                ;arg0 = how many places this value has.
                ;arg1 = home variable
                ;arg2 = amount to add ... places?
        ;; and this should trip the update hud flag?
        
        ;;;; 
    

	TXA
	STA tempy	;;dale_coop

	;AddValue #$08, myScore, #$01, #$00
	;STA hudElementTilesToLoad
	;UpdateHud HUD_myScore
	LDX tempy	;;dale_coop

        JSR HandleDrops
		
        ;;JSR HandleToggleScrolling	;; dale_coop removed handle scroll
		
		CountObjects #%00001000, #$00
		LDA monsterCounter
		CLC	;;dale_coop
		BEQ +
		JMP ++
	+
		.include SCR_KILLED_LAST_MONSTER
	++
        JMP skipHurtingMonster
    notMonsterDeath:
        STA Object_health,x
		PlaySound #SND_MONSTER_HURT
    skipHurtingMonster: 
        ;;PlaySound #SND_MONSTER_HURT
    
    skipHurtingMonsterAndSound:
        LDX tempx
		LDA Object_type,x
		;; we don't destroy the melee object
		CMP #OBJECT_PLAYER_MELEE
		BEQ +
        ;; what should we do with the projectile?
        DeactivateCurrentObject	;; destroy it ?
		+

HandlePlayerHurt_DC.asm:

Code:
;;;; To change invincibility time, knock back speed, or hurt duration
;;;; updating the abovevalues in constants.

playerGetsHurt:
	LDA Object_health,x
	CLC
	SEC
	SBC #$01 ;; subtract other's strength
	CMP #$01
	BCS notPlayerDeath
	
	JSR HandlePlayerDeath
	JMP doneWithPlayerHurt

notPlayerDeath:
	STA Object_health,x
	;;dale_coop player2:
	LDA player2Mode
	BEQ +
	CPX player2_object	
	BNE +
	LDA Object_health,x
	STA myHealth2
	;; update HUD :
	STA hudElementTilesToLoad
	UpdateHud HUD_myHealth2
    ;; TURN ON handling the hud
	JMP ++
	+
	LDA Object_health,x
	STA myHealth1
	;; update HUD :
	STA hudElementTilesToLoad
	UpdateHud HUD_myHealth1
    ;; TURN ON handling the hud
	++

	
	LDA Object_status,x
	ORA #%00000001
	STA Object_status,x	

	LDA #HURT_TIMER
	STA Object_timer_0,x
	ChangeObjectState #$00,#$02 ;; uses idle for hurt state.
	
	PlaySound #SND_HURT_PLAYER
	
	LDA selfCenterX
	STA recoil_selfX
	LDA selfCenterY
	STA recoil_selfY
	LDA otherCenterX
	STA recoil_otherX
	LDA otherCenterY
	STA recoil_otherY

	JSR DetermineRecoilDirection

	;;;;; SCROLLER CAN NOT MAKE USE OF UPDATING HUD THIS WAY.


	
doneWithPlayerHurt:
 

dale_coop

Moderator
Staff member
That HandleObjetCollision is NOT the one used by your project.
To find yours... check the "Project Settings > Script Settings", find the Handle Object Collision element, and see to what script this system element is assigned to.
I need your script.

(I think it should be assigned to a script that is located in the "Routines\Basic_NoScroll_TwoPlayers\ModuleScripts\MainScripts\SimplePlatformer\" folder)
Maybe your project uses a "HandleObjectCollisions_DCwithJumpOnKills.asm" script?
 

omniretro

New member
dale_coop said:
That HandleObjetCollision is NOT the one used by your project.
To find yours... check the "Project Settings > Script Settings", find the Handle Object Collision element, and see to what script this system element is assigned to.
I need your script.

(I think it should be assigned to a script that is located in the "Routines\Basic_NoScroll_TwoPlayers\ModuleScripts\MainScripts\SimplePlatformer\" folder)
Maybe your project uses a "HandleObjectCollisions_DCwithJumpOnKills.asm" script?

Yep, sorry, you are absolutely right--I just happened to be in Windows Explorer when I saw your reply so I grabbed what I thought were the correct files. My apologies!

I am in fact using HandleObjectCollisions_DCwithJumpOnKills.asm:

Code:
;; LOAD OBJECT 00
;; OUTER LOOP
;; CHECK IF ACTIVE, IF NOT, SKIP OBJECT
;; LOAD self-collision-box
;; START OBJECT COLLISION LOOP
    ;; LDA ONE MORE THAN CURRENT OBJECT
    ;; CHECK IF ACTIVE.  IF NOT, SKIP THIS other
    ;; IF IT IS ACTIVE, then we have to play them against each other.
        ;; IS self object hurt by monsters?  If so, and other object is a monster, respond.
        ;; IS self object hurt by weapons?  If so, and other object is a weapon, respond.
        ;; at this point, we can still gauge whether or not it's affected by player, like with powerups.
        ;; ADD one to the object being checked, loop through other objects.
;; increase object, return to outer loop.  Repeat thorugh all self objects.

;; ObjectFlags:
;; 7 - 6 - 5 - 4 - 3 - 2 - 1 - 0
;  |   |   |   |   |   |   |   + -- PERSISTENT (especially good for player!)
;  |   |   |   |   |   |   +------- player type
;  |   |   |   |   |   + ---------- player weapon/projectile type
;  |   |   |   |   +--------------- monster type
;  |   |   |   +------------------- monster weapon/projectile type
;  |   |   +----------------------- pickup / power up
;  |   + -------------------------- target type 
;  +------------------------------- NPC type

;; player type checks monster, mosnter weapon, and pickup.
;; player weapon checks monster and target.
;; nothing else needs checking, as it would all be handled by those two steps.
;; so if it's a monster, do nothing.  if it's a monster projectile, do nothing. 
;; if it's a pickup, or a target, or it ignores all collisions, do nothing.
;; only if it's #%00000110, do something.



HandleObjectCollisions:

    LDA update_screen
    BEQ notChangingScreens
    rts
notChangingScreens:
    
    LDA npc_collision
    AND #%11111110
    STA npc_collision
    LDA npc_collision2
    AND #%11111110
    STA npc_collision2

    ;LDA currentBank
    ;STA prevBank
    ;LDY #BANK_ANIMS
    ;JSR bankswitchY
    
    LDX #$00
CollisionOuterLoop:
    TXA
    STA tempx
    LDA Object_status,x
    AND #%10000000
    BNE continueObjectCollisions_objectIsActive
    JMP doneWithThisObjectCollision
continueObjectCollisions_objectIsActive:
    LDA Object_status,x
    AND #%00000100 ;; is ot off screen
    BEQ continueObjectCollisions_objectIsOnScreen
    JMP doneWithThisObjectCollision
continueObjectCollisions_objectIsOnScreen
    LDA Object_status,x
    AND #%00000011
    BEQ continueObjectCollisions_objectIsNotHurtOrInvincible
    JMP doneWithThisObjectCollision
continueObjectCollisions_objectIsNotHurtOrInvincible
    ;LDY Object_type,x
    ;LDA ObjectFlags,y
    LDA Object_flags,x
    AND #%00000110
    BNE continueObjectCollisions_onlyPlayerTypesCheck
    JMP doneWithThisObjectCollision
continueObjectCollisions_onlyPlayerTypesCheck:
    ;; this is either a player or player projectile type of object.
    ;; all other types will be taken care of by iterating through these two types.
    ;; first, check if it's player type.
    ;LdA ObjectFlags,y
    LDA Object_flags,x
    AND #%00000010
    BNE isPlayerTypeForCollision
    JMP notPlayerType_forObjectCollision
isPlayerTypeForCollision:
    ;;dale_coop player2
    LDA tempx
    CLC
    CMP player2_object
    BNE +
    STA playerX_object
    ;LDA #$01
    ;STA tempz
    LDA player2_object
    JMP ++
    +
    STA playerX_object
    ;LDA #$00
    ;STA tempz
    ;dale_coop player2
    LDA player1_object
    ++                  ;;dale_coop player2
    STA colX
    ;; is player type for object collision
    ;; player's index is loaded into tempx
    JSR GetSelfCollisionBox
    ;; now we have the collision box for self object
    ;; next we loop through objects.
    
    LDX #$00
LoopThroughOtherObjects_player:
    CPX tempx
    BNE dontSkipThisOtherObject
    JMP skipThisOtherObject ;; other object IS the player, the one doing the counting..
dontSkipThisOtherObject:
    LDA Object_status,x
    AND #%00000100
    BEQ dontSkipThisOtherObject_becauseOnScreen
    JMP skipThisOtherObject ;; because it was off screen.
dontSkipThisOtherObject_becauseOnScreen:

    JSR GetOtherCollisionBox
    

    ;; now we can do all the compares
    LDA selfNT_R
    CMP otherNT_L
    BCC + ;; no player object collision
    BNE ++ ;; is still possible to see collision.
    LDA selfRight
    CMP otherLeft
    BCC + ;; no player object collision
++ ;; it is still possible there is a collision here.
    LDA otherNT_R
    CMP selfNT_L
    BCC +
    BNE +++
    LDA otherRight
    CMP selfLeft
    BCC +
    
+++ ;; there was a collision here
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    LDA otherBottom
    CMP selfTop
    BCC +
    LDA selfBottom
    CMP otherTop
    BCC +

    JMP DoPlayerObjectCollision

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;    
+ ;; there is no collision here horizontally.
    JMP noPlayerObjectCollision

DoPlayerObjectCollision:


    
    LDA Object_flags,x
    AND #%10000000 ;; is it an NPC
    BNE isAnNPC
    ;; is not an NPC
    JMP isNotAnNPCcollision
isAnNPC:
    ;;;; do npc stuff.
    ;;;; enables a button to be used to activate a textbox.
    LDA Object_ID,x
    STA textVar
    ;LDA gameHandler
    ;ORA #%00100000
    ;STA gameHandler

    LDA playerX_object
    CMP player2_object
    BEQ +
    ;;;; npc collision with player 1:
    LDA npc_collision
    ORA #%00000001
    STA npc_collision
    JMP skipThisOtherObject
    +
    ;;;; npc collision with player 2:
    LDA npc_collision2
    ORA #%00000001
    STA npc_collision2
    JMP skipThisOtherObject

isNotAnNPCcollision:    
    LDA Object_flags,x
    ;LDA ObjectFlags,y
    AND #%00011000 ;; is it a monster type?
    BNE otherIsAMonsterTypeCollision
    JMP otherIsNotAMonsterTypeCollision
otherIsAMonsterTypeCollision:
    LDA Object_status,x
    AND #HURT_STATUS_MASK ;; if the monster is hurt, it can't hurt us
    BEQ yesPlayerObjectCollision
    JMP noPlayerObjectCollision
yesPlayerObjectCollision:
    
    LDA Object_vulnerability,x
    AND #%00000010 ;; in this module, this is ignore player collision
    BEQ doPlayerHurt

    JMP noPlayerObjectCollision
doPlayerHurt:
    ;;;observe health
    TXA
    STA tempxx ;; object is in tempx.
    
    LDX playerX_object

    LDA Object_status,x
    AND #HURT_STATUS_MASK
    BEQ playerWasNotHurtDuringCollision
    JMP playerWasHurtDuringCollision
playerWasNotHurtDuringCollision:

;;---- Jump On Kills code begin ----
    LDX tempxx
    LDA Object_vulnerability,x
    AND #%00010000
    BNE jumpOnMonster
    LDX playerX_object
    JMP dontJumpOnMonster
jumpOnMonster:
    LDX playerX_object

    LDA selfBottom
    CMP otherCenterY
    BCC +
    JMP dontJumpOnMonster
    +
    ;;; JUMP ON MONSTER
    LDA #$00
    SEC
    SBC #$04
    STA Object_v_speed_hi,x
    LDX tempxx
    LDA Object_x_hi,x
    STA temp
    LDA Object_y_hi,x
    STA temp1

    DeactivateCurrentObject 
    PlaySound #SND_SPLAT
    
    ;; INCREASE SCORE
    AddValue #$08, myScore, #$01, #$00
    UpdateHud HUD_myScore   

    LDX tempxx
    
    JSR HandleDrops
    ;; check for monter locks begin:
    CountObjects #%00001000, #$00
    LDA monsterCounter
    CLC
    BEQ +
    JMP ++
    +
        .include SCR_KILLED_LAST_MONSTER
    ;; check for monter locks end.
    ++  
    JMP playerWasHurtDuringCollision ;; just skips collision
dontJumpOnMonster:
;;---- Jump On Kills code end ----
    
    LDA Object_vulnerability,x
    AND #%01000000 ;; is he lethal invincible?
    BNE isLethalInvincible
    JMP notLethalInvincible
isLethalInvincible:
    LDX tempxx
    LDA Object_x_hi,x
    STA temp
    LDA Object_y_hi,x
    STA temp1
    ;CreateObject temp, temp1, #OBJ_MONSTER_DEATH, #$00, currentNametable ;; create "splat"
    ;LDX tempxx
    
    ;;; ordinarily we'll want to destroy the instance.
     DeactivateCurrentObject
    ;; incrase score, you killed a monster
    PlaySound #SND_MONSTER_DEATH
    ;TXA
    ;STA tempy
    ;AddValue #$08, myScore, #$01, #$00

    ;;; we also need to set up the routine to update the HUD
    ;; for this to work right, health must be a "blank-then-draw" type element.
    ;STA hudElementTilesToLoad
    ;   LDA #$00
    ;   STA hudElementTilesMax
        ; LDA DrawHudBytes
        ; ora #HUD_myScore
        ; STA DrawHudBytes
    ;UpdateHud HUD_myScore
    LDX tempxx
    ;;
    
    JSR HandleDrops
    ;; check for monter locks begin:
    CountObjects #%00001000, #$00
    LDA monsterCounter
    CLC
    BEQ +
    JMP ++
    +
        .include SCR_KILLED_LAST_MONSTER
    ;; check for monter locks end.
    ++  
    JMP skipThisOtherObject
    
notLethalInvincible:

    ;;;;;;;;;;;;;;;;;
    ;;;;;;;;; WHAT HAPPENS WHEN PLAYER IS HURT
    .include SCR_PLAYER_HURT_SCRIPT
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    
    
playerWasHurtDuringCollision:   
    LDX tempxx
    JMP skipThisOtherObject
otherIsNotAMonsterTypeCollision:
    ;LDA ObjectFlags,y
    LDA Object_flags,x
    AND #%00100000 ;; is it a 'collectable'?
    BEQ otherIsNotAcollectable
    ;;;; IS A pickup / power up
    DeactivateCurrentObject ;; makes the other object go away
                            ;; since other object is loaded in X
                            
;;=========== WHAT DO YOU WANT TO HAVE HAPPEN WHEN YOU COLLECT THIS ITEM?

    JSR HandlePickupPowerup

    
otherIsNotAcollectable:
noPlayerObjectCollision:    
skipThisOtherObject:
    INX
    CPX #TOTAL_MAX_OBJECTS
    BEQ doneLoopThroughOtherObjects_player
    JMP LoopThroughOtherObjects_player
doneLoopThroughOtherObjects_player:
    ;; end of player collision
    LDX tempx ;; restore x
    JMP doneWithThisObjectCollision
    
    
    
notPlayerType_forObjectCollision:
    ;; is of player weapon type.
    JSR GetSelfCollisionBox
    ;; now we have the collision box for self object
    ;; next we loop through objects.
    LDX #$00
LoopThroughOtherObjects_weapon:

    CPX tempx
    BNE dontskipThisOtherObject_weapon
    JMP skipThisOtherObject_weapon
dontskipThisOtherObject_weapon
    JSR GetOtherCollisionBox
    ;; now we can do all the compares
    LDA selfNT_R
    CMP otherNT_L
    BCC + ;; no player object collision
    BNE ++ ;; is still possible to see collision.
    LDA selfRight
    CMP otherLeft
    BCC + ;; no player object collision
++ ;; it is still possible there is a collision here.
    LDA otherNT_R
    CMP selfNT_L
    BCC +
    BNE +++
    LDA otherRight
    CMP selfLeft
    BCC +
    
+++ ;; there was a collision here
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    LDA otherBottom
    CMP selfTop
    BCC +
    LDA selfBottom
    CMP otherTop
    BCC +

    JMP doWeaponObjectCollision

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;    
+ ;; there is no collision here horizontally.
    JMP noWeaponObjectCollision
doWeaponObjectCollision:
    ;; go through the different types of collision possible.
    ;; first, check monster OR monser projectile, as that should lead to hurt/death
    ;LDY Object_type,x
    ;LDA ObjectFlags,y
    LDA Object_flags,x
    AND #%00001000 ;; is it a monster type?
    ;;; if you'd like the player weapon to ALSO destroy projectiles
    ;;; use #%00011000 here
    BNE otherIsMonsterTypeCollision_weapon
    JMP otherIsNotAMonsterTypeCollision_weapon
otherIsMonsterTypeCollision_weapon:
;;;;;;;;;;;;;;;;;;;;;;;;
    TXA
    PHA
    .include SCR_HANDLE_HURT_MONSTER
    PLA
    TAX
    ;;; if monster dies, count monsters
    ;; right now, he always dies, so count the monsters.
    ;;JSR countAllMonsters  
    

    
otherIsNotAMonsterTypeCollision_weapon:
    
noWeaponObjectCollision:    
skipThisOtherObject_weapon:
    INX
    CPX #TOTAL_MAX_OBJECTS
    BEQ doneWithLoopingThroughWeaponObjects
    JMP LoopThroughOtherObjects_weapon
doneWithLoopingThroughWeaponObjects:
    
    
    
    ;; end of player collision
    LDX tempx ;; restore x
    JMP doneWithThisObjectCollision
    
    
    
    
doneWithThisObjectCollision:
    LDX tempx
    INX
    CPX #TOTAL_MAX_OBJECTS
    BEQ doneWithAllObjects
    JMP CollisionOuterLoop
doneWithAllObjects:
    ;;;;;;;;;;;;;;;;;;;;;;;;;
    ;; for this module
    ;; we will check for the melee position.
    ;; but rather than waste space with an entire object
    ;; we'll just test it against a single point
    .include SCR_CHECK_SPRITE_WEAPON

    RTS
    
    
    
    
    
    
GetSelfCollisionBox:    
    LDA Object_x_hi,x
    CLC
    ADC Object_left,x
    STA selfLeft

    LDA Object_x_hi,x
    CLC
    ADC Object_right,x
    STA selfRight

    LDA Object_y_hi,x
    CLC
    ADC Object_top,x
    STA selfTop
    
    LDA Object_y_hi,x
    CLC
    ADC Object_bottom,x
    STA selfBottom
    LDA Object_x_hi,x
    CLC
    ADC Object_origin_x,x
    STA selfCenterX
    LDA Object_y_hi,x
    CLC
    ADC Object_origin_y,x
    STA selfCenterY
    

    RTS
    
GetOtherCollisionBox:
    LDA Object_x_hi,x
    CLC
    ADC Object_left,x
    STA otherLeft

    LDA Object_x_hi,x
    CLC
    ADC Object_right,x
    STA otherRight


    LDA Object_y_hi,x
    CLC
    ADC Object_top,x

    STA otherTop
    LDA Object_y_hi,x
    CLC
    ADC Object_bottom,x
    STA otherBottom
    LDA Object_x_hi,x
    CLC
    ADC Object_origin_x,x
    STA otherCenterX
    LDA Object_y_hi,x
    CLC
    ADC Object_origin_y,x
    STA otherCenterY
    

    RTS
    
    
    
    
    
    
    
DetermineRecoilDirection:

    ;;;RECOIL
    ;;First check for the abs x value
    LDA recoil_selfX
    SEC
    SBC recoil_otherX
    BCS absCheckDone
    EOR #$FF
    CLC
    ADC #$01
absCheckDone:
    STA temp
    LDA recoil_selfY
    SEC
    SBC recoil_otherY
    BCS absCheckDone2
    EOR #$FF
    CLC
    ADC #$01
absCheckDone2:
    CMP temp
    BCS vCol
    LDA recoil_selfX
    CMP recoil_otherX
    BCS recoilRight
    ;; recoil left
    ;LDX #$01
    LDA #RECOIL_SPEED_LO
    STA Object_h_speed_lo,x
    LDA #$00
    SEC
    SBC #RECOIL_SPEED_HI
    STA Object_h_speed_hi,x
    LDA #$00
    STA Object_v_speed_hi,x
    STA Object_v_speed_lo,x
    LDA #%10000000
    STA temp1
    LDA Object_movement,x
    AND #%00000111
    ORA temp1
    STA Object_movement,x
    RTS
    
recoilRight:
    ;LDX #$01
    LDA #RECOIL_SPEED_LO
    STA Object_h_speed_lo,x
    LDA #RECOIL_SPEED_HI
    STA Object_h_speed_hi,x
    LDA #$00
    STA Object_v_speed_hi,x
    STA Object_v_speed_lo,x
    LDA #%11000000
    STA temp1
    LDA Object_movement,x
    AND #%00000111
    ORA temp1
    STA Object_movement,x
    RTS
    
vCol:
    LDA recoil_selfY
    CMP recoil_otherY
    BCS recoilDown
    ;LDX #$01
    LDA #RECOIL_SPEED_LO
    STA Object_v_speed_lo,x
    LDA #$00
    SEC
    SBC #RECOIL_SPEED_HI
    STA Object_v_speed_hi,x
    LDA #%00100000
    STA temp1
    LDA #$00
    STA Object_h_speed_hi,x
    STA Object_h_speed_lo,x
    LDA Object_movement,x
    AND #%00000111
    ORA temp1
    STA Object_movement,x

    RTS
    
recoilDown:
    ;LDX #$01
    LDA #RECOIL_SPEED_LO
    STA Object_v_speed_lo,x
    LDA #RECOIL_SPEED_HI
    STA Object_v_speed_hi,x
    LDA #%00110000
    STA temp1
    LDA #$00
    STA Object_h_speed_hi,x
    STA Object_h_speed_lo,x
    LDA Object_movement,x
    AND #%00000111
    ORA temp1
    STA Object_movement,x
    
    RTS

(The other two ASM files I referenced are the right ones for sure, though.)
 

dale_coop

Moderator
Staff member
How do you kill the ennemis? jumping on them?
using projectiles? or weapon? (melee object or sprite based?)
 

dale_coop

Moderator
Staff member
Oh, ok...
Yeah, when the player is hurted (hurt timer), the engine skips all the collisions with any Monster.
no collision = can't jump on them
 

omniretro

New member
dale_coop said:
Oh, ok...
Yeah, when the player is hurted (hurt timer), the engine skips all the collisions with any Monster.
no collision = can't jump on them

It is what it is, then! I think I can live with this, I'll probably just warn the player about it in the instructions or something. Thanks for taking a look at this for me Mr. Coop!
 

dale_coop

Moderator
Staff member
Sorry... I think reorganizing the way the game engine comparisons are done for the objects, could be done, but I am worried that would cause slowdowns (or introduce new issues).
 
Top Bottom